Name	luajit
Description	Just-in-time compiler and drop-in replacement for Lua 5.1
Version	2.1.1767980792+707c12b-2
Package Base	luajit
Homepage	https://luajit.org/
Maintainers	['Caleb Maclennan <caleb@alerque.com>', 'Daurnimator <daurnimator@archlinux.org>', 'Lukas Fleischer <lfleischer@archlinux.org>', 'Tobias Powalowski <tpowa@archlinux.org>']
Contributors	['Anders Bergh <anders1@gmail.com>', 'Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Chris Brannon <chris@the-brannons.com>', 'Paulo Matias <matiasΘarchlinux-br·org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/luajit
Sources	['LuaJIT-707c12b.tar.gz::https://github.com/LuaJIT/LuaJIT/archive/707c12b.tar.gz']
Dependencies	['glibc', 'libgcc']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	[]
Builddate	16-02-2026 09:30:27
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	183796c62c8b59539344f69ef05251a8fc2fa4e40301e95943a89d782839b21c

# Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
# Maintainer: Daurnimator <daurnimator@archlinux.org>
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Chris Brannon <chris@the-brannons.com>
# Contributor: Paulo Matias <matiasΘarchlinux-br·org>
# Contributor: Anders Bergh <anders1@gmail.com>

pkgname=luajit
pkgver=2.1.1767980792+707c12b
_commit=${pkgver##*+}
pkgrel=2
pkgdesc='Just-in-time compiler and drop-in replacement for Lua 5.1'
arch=('x86_64')
url='https://luajit.org/'
license=('MIT')
depends=('glibc' 'libgcc')
source=("LuaJIT-${_commit}.tar.gz::https://github.com/LuaJIT/LuaJIT/archive/${_commit}.tar.gz")
sha256sums=('ac2defd1e9b4ab07ac0a52f2403318ffb0d54505b975dff0cfc49a927ab84d90')
b2sums=('10979e9a8ae6830b1e922120cdecd1274deed16a529b03e0b89d6305b366fddcca5e18dc3311b62ca53056f8bc9fbe3d823caff029077fee84ae8226bf486204')

build() {
  cd "LuaJIT-${_commit}"*/

  # Avoid early stripping
  make amalg PREFIX=/usr BUILDMODE=dynamic TARGET_STRIP=" @:"
}

check() {
  cd "LuaJIT-${_commit}"*/

  # Make sure that pkgver matches packaged commit
  local _ct=${pkgver##*.}
  test "${_ct%%+*}" == "$(cat .relver)"
}

package() {
  cd "LuaJIT-${_commit}"*/

  make install DESTDIR="$pkgdir" PREFIX=/usr
  install -Dm644 COPYRIGHT "$pkgdir/usr/share/licenses/$pkgname/COPYRIGHT"
}