Name	man-db
Description	A utility for reading man pages
Version	2.13.1-1
Package Base	man-db
Homepage	https://gitlab.com/man-db/man-db
Maintainers	['Andreas Radke <andyrtr@archlinux.org>']
Contributors	['Sergej Pupykin <sergej@aur.archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/man-db
Sources	['https://download-mirror.savannah.gnu.org/releases/man-db/man-db-2.13.1.tar.xz', 'https://download-mirror.savannah.gnu.org/releases/man-db/man-db-2.13.1.tar.xz.asc']
Dependencies	['bash', 'gdbm', 'glibc', 'groff', 'less', 'libpipeline', 'libseccomp', 'zlib']
Optional-Dependencies	['gzip']
Build-Dependencies	['po4a']
Provides	['man']
Builddate	03-05-2025 07:35:33
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-or-later AND GPL-3.0-or-later']
Hash	b24c76be9842190f25beff7fbdabaed9fce56d8cd880579b96a651e420c14f86

# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Sergej Pupykin <sergej@aur.archlinux.org>

pkgname=man-db
pkgver=2.13.1
pkgrel=1
pkgdesc="A utility for reading man pages"
arch=('x86_64')
url="https://gitlab.com/man-db/man-db"
license=('GPL-2.0-or-later AND GPL-3.0-or-later')
depends=( 'bash' 'gdbm' 'zlib' 'groff' 'libpipeline' 'less' 'libseccomp' 'glibc')
makedepends=('po4a')
optdepends=('gzip') # covered by virtual "base" package
backup=('etc/man_db.conf')
conflicts=('man')
provides=('man')
replaces=('man')
install=${pkgname}.install
source=(#https://savannah.nongnu.org/download/man-db/$pkgname-$pkgver.tar.xz{,.asc}
        # fallback should be used within first 24h after a release
        https://download-mirror.savannah.gnu.org/releases/man-db/$pkgname-$pkgver.tar.xz{,.asc} 
)
validpgpkeys=('AC0A4FF12611B6FCCF01C111393587D97D86500B') # Colin Watson <cjwatson@debian.org>
sha512sums=('9b39f512fe940e648ca7f47803f42e473064253b67eb96995d28da30fd322de31a4466bf821e9391e6041af2318a6d2c2d74102b73f4b42a63966b41d2df0578'
            'SKIP')

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
    --sbindir=/usr/bin \
    --sysconfdir=/etc \
    --libexecdir=/usr/lib \
    --with-systemdsystemunitdir=/usr/lib/systemd/system \
    --with-snapdir=/var/lib/snapd/snap \
    --with-db=gdbm \
    --disable-setuid \
    --enable-cache-owner=root \
    --enable-mandirs=GNU \
    --with-sections="1 1p n l 8 3 3p 0 0p 2 3type 5 4 9 6 7"
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install

  # part of groff pkg
  rm -f ${pkgdir}/usr/bin/zsoelim

  install -d -m755 ${pkgdir}/usr/lib/systemd/system/timers.target.wants
  ln -s ../man-db.timer ${pkgdir}/usr/lib/systemd/system/timers.target.wants/man-db.timer
}