Name	mkinitcpio-busybox
Description	Base initramfs tools
Version	1.36.1-1
Package Base	mkinitcpio-busybox
Homepage	https://www.busybox.net/
Maintainers	['Giancarlo Razzolini <grazzolini@archlinux.org>']
Contributors	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Dave Reisner <dreisner@archlinux.org>', 'Thomas Bächler <thomas@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/mkinitcpio-busybox
Sources	['config', 'https://busybox.net/downloads/busybox-1.36.1.tar.bz2', 'https://busybox.net/downloads/busybox-1.36.1.tar.bz2.sig']
Dependencies	['glibc', 'libxcrypt']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	[]
Builddate	26-06-2023 18:09:54
Architecture	x86_64
Distro-Version
Licenses	['GPL']
Hash	573182e5dc39f49146d73e201bb2193372cc514e3a0fd09128205717a4fb558d

# Maintainer: Giancarlo Razzolini <grazzolini@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Dave Reisner <dreisner@archlinux.org>
# Contributor: Thomas Bächler <thomas@archlinux.org>

pkgname=mkinitcpio-busybox
pkgver=1.36.1
pkgrel=1
pkgdesc='Base initramfs tools'
arch=(x86_64)
url="https://www.busybox.net/"
license=(GPL)
depends=(glibc libxcrypt)
options=(!buildflags)
source=(https://busybox.net/downloads/busybox-$pkgver.tar.bz2{,.sig}
        config)
sha256sums=('b8cc24c9574d809e7279c3be349795c5d5ceb6fdf19ca709f80cde50e47de314'
            'SKIP'
            'f1a67ecda5b73a50e49953efaaa0be582e4b707cf5a6270519e28ee022098518')
validpgpkeys=('C9E9416F76E610DBD09D040F47B70C55ACC9965B') # Denis Vlasenko <vda.linux@googlemail.com>

prepare() {
  cd "busybox-$pkgver"
  
  local safeflags="-march=${CARCH/_/-} -mtune=generic -Os -pipe -fno-strict-aliasing"

  # use make oldconfig for updating the config file
  sed 's|^\(CONFIG_EXTRA_CFLAGS\)=.*|\1="'"$safeflags"'"|' "$srcdir/config" > .config
}

build() {
  # reproducible build
  export KCONFIG_NOTIMESTAMP=1
  make -C "busybox-$pkgver"
}

package() {
  install -Dm755 "$srcdir/busybox-$pkgver/busybox" "$pkgdir/usr/lib/initcpio/busybox"
}