Name	mpg123
Description	Console based real time MPEG Audio Player for Layer 1, 2 and 3
Version	1.33.4-1
Package Base	mpg123
Homepage	https://mpg123.de/
Maintainers	['Levente Polyak <anthraxx[at]archlinux[dot]org>', 'T.J. Townsend <blakkheim@archlinux.org>']
Contributors	['Eric Bélanger <eric@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/mpg123
Sources	['https://downloads.sourceforge.net/sourceforge/mpg123/mpg123-1.33.4.tar.bz2', 'https://downloads.sourceforge.net/sourceforge/mpg123/mpg123-1.33.4.tar.bz2.sig']
Dependencies	['alsa-lib']
Optional-Dependencies	['jack', 'libpulse', 'perl', 'sdl2']
Build-Dependencies	['sdl2', 'jack', 'libpulse']
Provides	['libmpg123.so', 'libout123.so', 'libsyn123.so']
Builddate	22-12-2025 16:38:28
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-only']
Hash	23d350b6e924f8b49d43a0c6862453208090d8e739a2f157b355cd653ead35b9

# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Eric Bélanger <eric@archlinux.org>

pkgname=mpg123
pkgver=1.33.4
pkgrel=1
pkgdesc='Console based real time MPEG Audio Player for Layer 1, 2 and 3'
url='https://mpg123.de/'
arch=('x86_64')
license=('LGPL-2.1-only')
depends=('alsa-lib')
makedepends=('sdl2' 'jack' 'libpulse')
optdepends=(
  'sdl2: for sdl audio support'
  'jack: for jack audio support'
  'libpulse: for pulse audio support'
  'perl: for conplay'
)
provides=(lib{mpg,out,syn}123.so)
source=(https://downloads.sourceforge.net/sourceforge/mpg123/mpg123-${pkgver}.tar.bz2{,.sig})
sha512sums=('9b7aa93b692132da7eb8dcfef12ce91bf66bf8475af50e9c57d7b80225f96c0e74264e518e558371af1f4cf6d2afda5b3dfc844949fd747db7ac7c44d0e9f6ad'
            'SKIP')
validpgpkeys=('D021FF8ECF4BE09719D61A27231C4CBC60D5CAFE')

build() {
  cd mpg123-${pkgver}
  ./configure \
    --prefix=/usr \
    --enable-int-quality \
    --with-audio="alsa oss sdl jack pulse"
  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd mpg123-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm 755 scripts/conplay -t "${pkgdir}/usr/bin"
}

# vim:set sw=2 sts=-1 et: