Name	ocl-icd
Description	OpenCL ICD Bindings
Version	2.3.4-1
Package Base	ocl-icd
Homepage	https://github.com/OCL-dev/ocl-icd
Maintainers	['Laurent Carlier <lordheavym@gmail.com>', 'Peter Jung <ptr1337@archlinux.org>']
Contributors	['Lukas Jirkovsky <l.jirkovsky@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/ocl-icd
Sources	['ocl-icd-2.3.4.tar.gz::https://github.com/OCL-dev/ocl-icd/archive/v2.3.4.tar.gz']
Dependencies	['glibc']
Optional-Dependencies	['opencl-driver']
Build-Dependencies	['ruby', 'mesa', 'xmlto', 'asciidoc', 'opencl-headers']
Provides	['opencl-icd-loader']
Builddate	07-11-2025 14:28:11
Architecture	x86_64
Distro-Version
Licenses	['BSD-2-Clause']
Hash	64354d210d8504da27a989aab165b12f7283177c729a79532a3caf3c02c0ed5e

# Maintainer: Laurent Carlier <lordheavym@gmail.com>
# Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>

pkgname=ocl-icd
pkgver=2.3.4
pkgrel=1
pkgdesc="OpenCL ICD Bindings"
arch=('x86_64')
url="https://github.com/OCL-dev/ocl-icd"
license=('BSD-2-Clause')
depends=('glibc')
makedepends=('ruby' 'mesa' 'xmlto' 'asciidoc' 'opencl-headers>=2.1')
checkdepends=()
provides=('opencl-icd-loader')
conflicts=('libcl')
replaces=('libcl')
optdepends=('opencl-driver: packaged opencl driver')
source=("ocl-icd-${pkgver}.tar.gz::https://github.com/OCL-dev/${pkgname}/archive/v${pkgver}.tar.gz")
sha256sums=('1a302b71b7304cca5a36f69d017b1af2b762cc4c2dd1c0c0e2fc1933db25c9cc')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  autoreconf -fiv
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  ./configure --prefix=/usr
  make
}

check() {
  cd "$srcdir/$pkgname-$pkgver"
  make -k check
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install

  install -m755 -d "$pkgdir/usr/share/licenses/ocl-icd"
  install -m644 "$srcdir/$pkgname-$pkgver/COPYING" "${pkgdir}/usr/share/licenses/ocl-icd/"
}

# vim:set ts=2 sw=2 et: