Name	openjpeg2
Description	An open source JPEG 2000 codec, version 2.5.4
Version	2.5.4-1
Package Base	openjpeg2
Homepage	https://github.com/uclouvain/openjpeg
Maintainers	['Andreas Radke <andyrtr@archlinux.org>']
Contributors	['Sergej Pupykin <pupykin.s+arch@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/openjpeg2
Sources	['openjpeg2-2.5.4.tar.gz::https://github.com/uclouvain/openjpeg/archive/v2.5.4.tar.gz']
Dependencies	['glibc', 'lcms2', 'libpng', 'libtiff']
Optional-Dependencies	[]
Build-Dependencies	['cmake', 'doxygen', 'graphviz']
Provides	[]
Builddate	26-09-2025 07:48:53
Architecture	x86_64
Distro-Version
Licenses	['BSD-2-Clause', 'MIT']
Hash	f09d64baeda07bc9bc0bb6a08b5f316db372bedd100b9a56f44ffaeace26c1e6

# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>

pkgname=openjpeg2
pkgver=2.5.4
pkgrel=1
pkgdesc="An open source JPEG 2000 codec, version ${pkgver}"
arch=(x86_64)
license=('BSD-2-Clause' 'MIT')
url="https://github.com/uclouvain/openjpeg"
makedepends=('cmake' 'doxygen' 'graphviz')
depends=('libpng' 'libtiff' 'lcms2' 'glibc')
source=("$pkgname-$pkgver.tar.gz::https://github.com/uclouvain/openjpeg/archive/v$pkgver.tar.gz")
sha256sums=('a695fbe19c0165f295a8531b1e4e855cd94d0875d2f88ec4b61080677e27188a')

prepare() {
  # Remove all third party libraries just to be sure
  find openjpeg-"${pkgver}"/thirdparty/ -mindepth 1 -maxdepth 1 -type d -exec rm -rf {} \;
}

build() {
  cmake -B build -S openjpeg-"${pkgver}" \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DBUILD_SHARED_LIBS=ON \
    -DBUILD_STATIC_LIBS=OFF \
    -DBUILD_DOC=on

  VERBOSE=1 cmake --build build
}

check() {
  ctest --test-dir build --output-on-failure
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -Dm 644 "${srcdir}"/openjpeg-"${pkgver}"/LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}/  
}