Name	orc
Description	Optimized Inner Loop Runtime Compiler
Version	0.4.42-1
Package Base	orc
Homepage	https://gstreamer.freedesktop.org/modules/orc.html
Maintainers	['Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Ionut Biru <ibiru@archlinux.org>', 'Jan de Groot <jgc@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/orc
Sources	['git+https://gitlab.freedesktop.org/gstreamer/orc.git?signed#tag=0.4.42']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['clang', 'git', 'hotdoc', 'llvm', 'meson', 'valgrind']
Provides	['liborc-0.4.so', 'liborc-test-0.4.so']
Builddate	29-01-2026 06:38:18
Architecture	x86_64
Distro-Version
Licenses	['BSD-3-Clause']
Hash	0c7df3cb2274b72565ca51f1a56d3ab2cf75c019e1da228780a2ed0833494b1d

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgbase=orc
pkgname=(
  orc
  orc-docs
)
pkgver=0.4.42
pkgrel=1
pkgdesc="Optimized Inner Loop Runtime Compiler"
url="https://gstreamer.freedesktop.org/modules/orc.html"
arch=(x86_64)
license=(BSD-3-Clause)
depends=(
  glibc
)
makedepends=(
  clang
  git
  hotdoc
  llvm
  meson
  valgrind
)
source=("git+https://gitlab.freedesktop.org/gstreamer/orc.git?signed#tag=$pkgver")
b2sums=('65b8fc3a403fb0eeb89edf865f8631bc56997149ef8e09a6a20a5e36a2fea84ab1b5cc7e916e0016d3e49cdc188957279f16baba615648bc7c7dbaf7f57e791a')
validpgpkeys=(
  D637032E45B8C6585B9456565D2EEE6F6F349D7C # Tim-Philipp Müller <tim@centricular.com>
)

prepare() {
  cd orc
}

build() {
  arch-meson orc build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package_orc() {
  provides=(liborc{,-test}-${pkgver%.*}.so)

  meson install -C build --destdir "$pkgdir"
  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 orc/COPYING

  mkdir -p doc/usr/share
  mv {"$pkgdir",doc}/usr/share/doc
}

package_orc-docs() {
  pkgdesc+=" (documentation)"
  depends=()

  mv doc/* "$pkgdir"
  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 orc/COPYING
}

# vim:set sw=2 sts=-1 et: