Name	pacman-contrib
Description	Contributed scripts and tools for pacman systems
Version	1.13.1-1
Package Base	pacman-contrib
Homepage	https://gitlab.archlinux.org/pacman/pacman-contrib
Maintainers	['Daniel M. Capella <polyzen@archlinux.org>', 'Johannes Löthberg <johannes@kyriasis.com>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/pacman-contrib
Sources	['git+https://gitlab.archlinux.org/pacman/pacman-contrib.git#tag=v1.13.1']
Dependencies	['pacman']
Optional-Dependencies	['diffutils', 'fakeroot', 'findutils', 'mlocate', 'neovim', 'perl', 'plocate', 'sudo', 'vim']
Build-Dependencies	['asciidoc', 'git']
Provides	[]
Builddate	11-12-2025 21:58:40
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-or-later']
Hash	190d0a557a7863023007407832bf8003345e12ee9cc39f6e3c740b4b56cd234e

# Maintainer: Johannes Löthberg <johannes@kyriasis.com>
# Maintainer: Daniel M. Capella <polyzen@archlinux.org>

pkgname=pacman-contrib
pkgver=1.13.1
pkgrel=1
pkgdesc='Contributed scripts and tools for pacman systems'
arch=(x86_64)
url=https://gitlab.archlinux.org/pacman/pacman-contrib
license=(GPL-2.0-or-later)
depends=(pacman)
makedepends=(
  asciidoc
  git
)
optdepends=(
  'diffutils: for pacdiff'
  'fakeroot: for checkupdates'
  'findutils: for pacdiff --find'
  'mlocate: for pacdiff --locate'
  'plocate: faster mlocate alternative'
  'perl: for pacsearch'
  'sudo: privilege elevation for several scripts'
  'vim: default diff program for pacdiff'
  'neovim: default diff program for pacdiff if EDITOR=nvim'
)
source=("git+$url.git#tag=v$pkgver")
b2sums=('cf1396aa108c6742d74a369456dfdf6a83286c0e8996b730ed16fa8907d0253ebb49ddcd6b548959d5df8d30af223d7883bbabda9e1dfb006d175400e37a105f')
validpgpkeys=(04DC3FB1445FECA813C27EFAEA4F7B321A906AD9 44A62127789A949F2F082ED429C71CE612B57264) # Daniel M. Capella <polyzen@archlinux.org>
#             5134EF9EAF65F95B6BB1608E50FB9B273A9D0BB5)  # Johannes Löthberg <johannes@kyriasis.com>

prepare() {
  cd $pkgname
  ./autogen.sh
}

build() {
  cd $pkgname
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var
  make
}

check() {
  cd $pkgname
  make check
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: