Name	pam
Description	PAM (Pluggable Authentication Modules) library
Version	1.7.2-2
Package Base	pam
Homepage	http://linux-pam.org
Maintainers	['Levente Polyak <anthraxx[at]archlinux[dot]org>', 'Tobias Powalowski <tpowa@archlinux.org>']
Contributors	['judd <jvinet@zeroflux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/pam
Sources	['pam.tmpfiles', 'pam::git+https://github.com/linux-pam/linux-pam?signed#tag=v1.7.2']
Dependencies	['audit', 'glibc', 'libaudit.so', 'libcrypt.so', 'libnsl', 'libtirpc', 'libxcrypt', 'pambase', 'systemd-libs']
Optional-Dependencies	[]
Build-Dependencies	['docbook-xml', 'docbook-xsl', 'docbook5-xml', 'flex', 'fop', 'git', 'libxslt', 'meson', 'w3m']
Provides	['libpam.so', 'libpamc.so', 'libpam_misc.so']
Builddate	26-01-2026 15:40:50
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-only']
Hash	49f54d6b632d0e83cde032eb01f903b71ac09e7dc9bbafbd64fea70227337d48

# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: judd <jvinet@zeroflux.org>

pkgname=pam
pkgver=1.7.2
pkgrel=2
pkgdesc="PAM (Pluggable Authentication Modules) library"
arch=('x86_64')
license=('GPL-2.0-only')
url="http://linux-pam.org"
depends=(
  audit
  glibc
  libaudit.so
  libcrypt.so
  libnsl
  libtirpc
  libxcrypt
  pambase
  systemd-libs
)
makedepends=(
  docbook-xml
  docbook-xsl
  docbook5-xml
  flex
  fop
  git
  libxslt
  meson
  w3m
)
provides=(
  libpam.so
  libpamc.so
  libpam_misc.so
)
backup=(
  etc/security/{access.conf,faillock.conf,group.conf,limits.conf,namespace.conf,namespace.init,pwhistory.conf,pam_env.conf,time.conf} 
  etc/environment
)
source=("pam::git+https://github.com/linux-pam/linux-pam?signed#tag=v${pkgver}"
        "${pkgname}.tmpfiles")
validpgpkeys=(
        '8C6BFD92EE0F42EDF91A6A736D1A7F052E5924BB' # Thorsten Kukuk
        '296D6F29A020808E8717A8842DB5BD89A340AEB7' # Dimitry V. Levin <ldv@altlinux.org>
        '7BECFE3AF7B280BB52FF77F104BA4521C996DDE1' # Dmitry V. Levin <ldv@strace.io
)
b2sums=('7fac16161ee8abab8639f5661badcf29536f0df71fec085075b657f91264fa7e616ae74c60e77fd8503d767517847dda877f583f20ca354e2ba45a381d89c998'
        '36582c80020008c3810b311a2e126d2fb4ffc94e565ea4c0c0ab567fdb92943e269781ffa548550742feb685847c26c340906c7454dcc31df4e1e47d511d8d6f')
options=('!emptydirs')

prepare() {
  cd "${pkgname}"
  # apply patch from the source array (should be a pacman feature)
  local src
  for src in "${source[@]}"; do
    src="${src%%::*}"
    src="${src##*/}"
    [[ $src = *.patch ]] || continue
    echo "Applying patch ${src}..."
    patch -Np1 < "../${src}"
  done
}

build() {
  arch-meson "${pkgname}" \
    -Dlogind=enabled \
    -Deconf=disabled \
    -Dselinux=disabled \
    -Delogind=disabled \
    -Dpam_userdb=disabled \
    -Dpwaccess=disabled \
    -Dvendordir='' \
    build
  meson compile -C build
}

check() {
  meson test -C build
}

package() {
  meson install -C build --destdir "${pkgdir}"
  install -Dm 644 $pkgname.tmpfiles "${pkgdir}"/usr/lib/tmpfiles.d/${pkgname}.conf

  # remove unreproducible pdf files
  rm "${pkgdir}"/usr/share/doc/Linux-PAM/*.pdf

  # set unix_chkpwd uid
  chmod +s "${pkgdir}"/usr/bin/unix_chkpwd
}