Name	patch
Description	A utility to apply patch files to original sources
Version	2.8-1
Package Base	patch
Homepage	https://www.gnu.org/software/patch/
Maintainers	['Christian Hesse <eworm@archlinux.org>', 'Sébastien Luttringer <seblu@archlinux.org>']
Contributors	['Allan McRae <allan@archlinux.org>', 'Levente Polyak <anthraxx[at]archlinux[dot]org>', 'judd <jvinet@zeroflux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/patch
Sources	['git+https://git.savannah.gnu.org/git/gnulib.git', 'git+https://git.savannah.gnu.org/git/patch.git#tag=v2.8?signed']
Dependencies	['attr', 'glibc']
Optional-Dependencies	['ed']
Build-Dependencies	['ed', 'git', 'python']
Provides	[]
Builddate	15-04-2025 17:22:47
Architecture	x86_64
Distro-Version
Licenses	['GPL']
Hash	b4685fc56dfc18afb754f64099b82396885fefe43e82f20b37477650f642303c

# Maintainer: Sébastien Luttringer <seblu@archlinux.org>
# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>

pkgname=patch
pkgver=2.8
pkgrel=1
pkgdesc='A utility to apply patch files to original sources'
arch=('x86_64')
url='https://www.gnu.org/software/patch/'
license=('GPL-3.0-or-later')
depends=('glibc' 'attr')
makedepends=('ed' 'git' 'python')
optdepends=('ed: for patch -e functionality')
validpgpkeys=('259B3792B3D6D319212CC4DCD5BF9FEB0313653A') # Andreas Gruenbacher <andreas.gruenbacher@gmail.com>
source=("git+https://git.savannah.gnu.org/git/patch.git#tag=v${pkgver}?signed"
        "git+https://git.savannah.gnu.org/git/gnulib.git")
sha256sums=('e5dc0235f8ecdf22002dd3a22e80238502968e5be960e63a47dcd9a1c55ec6b3'
            'SKIP')

prepare() {
  cd "${pkgname}"

  git submodule init
  git config submodule.gnulib.url "${srcdir}/gnulib"
  git -c protocol.file.allow=always submodule update

  ./bootstrap
}

build() {
  cd "${pkgname}"
  ./configure --prefix=/usr
  make
}

check() {
  cd "${pkgname}"
  make check
}

package() {
  cd "${pkgname}"
  make DESTDIR="${pkgdir}" install
}

# vim:set ts=2 sw=2 et: