Name	pixman
Description	The pixel-manipulation library for X and cairo
Version	0.46.4-1
Package Base	pixman
Homepage	https://gitlab.freedesktop.org/pixman/pixman
Maintainers	['Andreas Radke <andyrtr@archlinux.org>']
Contributors	['Alexander Baldeck <alexander@archlinux.org>', 'Jan de Groot <jgc@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/pixman
Sources	['https://www.x.org/releases/individual/lib/pixman-0.46.4.tar.xz']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['meson', 'libpng']
Provides	['libpixman-1.so']
Builddate	20-07-2025 18:54:37
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	e87e665d25a2230a178d8490202e1d677fde5908f68ebedf7d987308fc26fcb6

# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Alexander Baldeck <alexander@archlinux.org>

pkgname=pixman
pkgver=0.46.4
pkgrel=1
pkgdesc="The pixel-manipulation library for X and cairo"
arch=(x86_64)
url="https://gitlab.freedesktop.org/pixman/pixman"
license=('MIT')
depends=('glibc')
makedepends=('meson' 'libpng')
provides=('libpixman-1.so')
source=(https://www.x.org/releases/individual/lib/${pkgname}-${pkgver}.tar.xz)
sha512sums=('83b133e7969ba34f883f4e08dcc5d388c4397f43ce836c191c05945fe77c16ff501d531600780c12678a0d08105828a6bdeff2156b63f9c1a84087bc7f40ae9f')
#validpgpkeys=('') # Maarten Lankhorst <maarten.lankhorst@linux.intel.com>

build() {
  local _mesonopts=(
    -D loongson-mmi=disabled
    -D vmx=disabled
    -D arm-simd=disabled
    -D neon=disabled
    -D mips-dspr2=disabled
    -D rvv=disabled
    -D gtk=disabled
  )

  if [[ $CARCH == "x86_64" ]]; then
    _mesonopts+=(
      -D a64-neon=disabled
    )
  fi

  if [[ $CARCH == "aarch64" ]]; then
    _mesonopts+=(
      -D mmx=disabled
      -D sse2=disabled
      -D ssse3=disabled
    )
  fi

  arch-meson $pkgname-$pkgver build "${_mesonopts[@]}"
  ninja -C build
}

check() {
  meson test -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname-$pkgver/COPYING
}