Name	pkgconf
Description	Package compiler and linker metadata toolkit
Version	2.5.1-1
Package Base	pkgconf
Homepage	https://github.com/pkgconf/pkgconf
Maintainers	['Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Bartlomiej Piotrowski <nospam@bpiotrowski.pl>', 'Johannes Löthberg <johannes@kyriasis.com>', 'Lucy <lucy@luz.lu>', 'Piotr Gorski <lucjan.lucjanov@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/pkgconf
Sources	['git+https://github.com/pkgconf/pkgconf#tag=pkgconf-2.5.1', 'i686-pc-linux-gnu.personality', 'x86_64-pc-linux-gnu.personality']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['git', 'meson']
Provides	['libpkgconf.so', 'pkg-config', 'pkgconfig']
Builddate	25-06-2025 04:06:54
Architecture	x86_64
Distro-Version
Licenses	['ISC']
Hash	8c56b6f08ea227881a6cad0d42b039175108923fb002957a4e5e09ace4d931fc

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Johannes Löthberg <johannes@kyriasis.com>
# Contributor: Piotr Gorski <lucjan.lucjanov@gmail.com>
# Contributor: Lucy <lucy@luz.lu>
# Contributor: Bartlomiej Piotrowski <nospam@bpiotrowski.pl>

pkgname=pkgconf
pkgver=2.5.1
pkgrel=1
pkgdesc="Package compiler and linker metadata toolkit"
url="https://github.com/pkgconf/pkgconf"
license=(ISC)
arch=(x86_64)
depends=(
  glibc
)
makedepends=(
  git
  meson
)
provides=(
  libpkgconf.so
  pkg-config
  pkgconfig
)
conflicts=(pkg-config)
replaces=(pkg-config)
source=(
  "git+$url#tag=pkgconf-$pkgver"
  {x86_64,i686}-pc-linux-gnu.personality
)
b2sums=('d0dedc79397bb4ccf9b8c117fd8aa72cb22ef1ae45fd45748a8befe18ece31fe21d39010751806c0bad0ad8ce1a3d9c6750b67ac8378361c336e21a3d4a23073'
        'c04583e19149c1035cb7777a59f0fbc4988b672d8e45105e33def3d0f9054464e33a400a3e7c7e8b99b334e4fe06aaa9d7e34662e806096d4374bd6b12d803db'
        '94c8fd12b5f33611fd6dbeae03b20e72bcf2937e764766e2633b2fd4c14925860d57eee234016c81b0563a47b112ac9ef4a8b3bb9fa3fc0dd266f355bc156c58')

prepare() {
  cd pkgconf
}

build() {
  local meson_options=(
    -D tests=disabled  # Tests need kyua
  )

  arch-meson pkgconf build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"

  local p
  for p in *.personality; do
    install -Dm644 "$p" -t "$pkgdir/usr/share/pkgconfig/personality.d"
    ln -s pkgconf "$pkgdir/usr/bin/${p%.*}-pkg-config"
  done

  ln -s pkgconf "$pkgdir/usr/bin/pkg-config"
  ln -s pkgconf.1 "$pkgdir/usr/share/man/man1/pkg-config.1"

  install -Dm644 pkgconf/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}

# vim:set sw=2 sts=-1 et: