Name	procps-ng
Description	Utilities for monitoring your system and its processes
Version	4.0.6-1
Package Base	procps-ng
Homepage	https://gitlab.com/procps-ng/procps
Maintainers	['Christian Hesse <eworm@archlinux.org>', 'Levente Polyak <anthraxx[at]archlinux[dot]org>']
Contributors	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Christian Hesse <eworm@archlinux.org>', 'Eric Bélanger <eric@archlinux.org>', 'Gaetan Bisson <bisson@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/procps-ng
Sources	['git+https://gitlab.com/procps-ng/procps.git#tag=v4.0.6?signed']
Dependencies	['glibc', 'libncursesw.so', 'ncurses', 'systemd-libs']
Optional-Dependencies	[]
Build-Dependencies	['gettext', 'git', 'po4a', 'systemd']
Provides	['procps', 'sysvinit-tools', 'libproc2.so']
Builddate	29-01-2026 11:01:28
Architecture	x86_64
Distro-Version
Licenses	['GPL', 'LGPL']
Hash	96f6bf41c1718c143654ea2e7d4fdbf0d5e51c79f24f37b014f8d6e0c9c49913

# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Christian Hesse <eworm@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Eric Bélanger <eric@archlinux.org>

pkgname=procps-ng
pkgver=4.0.6
pkgrel=1
pkgdesc='Utilities for monitoring your system and its processes'
url='https://gitlab.com/procps-ng/procps'
license=(GPL LGPL)
arch=(x86_64)
depends=(glibc ncurses libncursesw.so systemd-libs)
makedepends=(gettext git po4a systemd)
conflicts=(procps sysvinit-tools)
provides=(procps sysvinit-tools libproc2.so)
replaces=(procps sysvinit-tools)
options=('!emptydirs')
validpgpkeys=('5D2FB320B825D93904D205193938F96BDF50FEA5') # Craig Small <csmall@debian.org>
source=("git+https://gitlab.com/procps-ng/procps.git#tag=v${pkgver}?signed")
sha256sums=('160aa30e2a133f44e7cc6e90c16cc018360a786f043aef84614ce595062fc894')
b2sums=('fe36c3c3c38882e09c47f7865015c5f8fc82e7432cb427ca21ad3712a112025daeba395b118ba81245727443407fb6666cf4ffea1f2ce1f605a8c5bbe8508db2')

prepare() {
  cd procps

  ./autogen.sh
}

build() {
  cd procps

  ./configure \
    --prefix=/usr \
    --exec-prefix=/ \
    --sysconfdir=/etc \
    --libdir=/usr/lib \
    --bindir=/usr/bin \
    --sbindir=/usr/bin \
    --enable-watch8bit \
    --with-systemd \
    --disable-modern-top \
    --disable-kill

  make
}

package() {
  cd procps

  make DESTDIR="$pkgdir" install
}