Name	python-charset-normalizer
Description	Encoding and language detection alternative to chardet
Version	3.4.4-2
Package Base	python-charset-normalizer
Homepage	https://github.com/Ousret/charset_normalizer
Maintainers	['Daniel M. Capella <polyzen@archlinux.org>', 'Jelle van der Waa <jelle@archlinux.org>']
Contributors	['Dimitris Kiziridis <ragouel@outlook.com>', 'Maxime Gauduin <alucryd@archlinux.org>', 'lilac <lilac@build.archlinuxcn.org>', 'lilydjwg <lilydjwg@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/python-charset-normalizer
Sources	['git+https://github.com/Ousret/charset_normalizer.git#tag=3.4.4']
Dependencies	['python']
Optional-Dependencies	[]
Build-Dependencies	['git', 'mypy', 'python-build', 'python-installer', 'python-setuptools', 'python-wheel']
Provides	[]
Builddate	14-12-2025 12:54:58
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	3785c931419902d88a35fb1b79b9c1f33474a6a777311787a65d873e79ed30f5

# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: lilydjwg <lilydjwg@gmail.com>
# Contributor: lilac <lilac@build.archlinuxcn.org>
# Contributor: Dimitris Kiziridis <ragouel@outlook.com>

_name=charset_normalizer
pkgname=python-charset-normalizer
pkgver=3.4.4
pkgrel=2
pkgdesc='Encoding and language detection alternative to chardet'
arch=(x86_64)
url=https://github.com/Ousret/charset_normalizer
license=(MIT)
depends=(python)
makedepends=(
  git
  mypy
  python-build
  python-installer
  python-setuptools
  python-wheel
)
checkdepends=(python-pytest)
source=("git+$url.git#tag=$pkgver")
b2sums=('2498874ce6619749dfac4cf201cb27425a59316fef5e5ac145c895103782fbdf413df2b65436603ab301722b16ae312667766866a09a611f46753ec3b22fbb37')

build() {
  cd $_name
  export CHARSET_NORMALIZER_USE_MYPYC=1
  python -m build --wheel --skip-dependency-check --no-isolation
}

check() {
  cd $_name
  PYTHONPATH=src pytest
}

package() {
  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  install -d "$pkgdir"/usr/share/licenses/$pkgname
  ln -s "$site_packages"/$_name-$pkgver.dist-info/licenses/LICENSE \
    "$pkgdir"/usr/share/licenses/$pkgname

  cd $_name
  python -m installer --destdir="$pkgdir" dist/*.whl
}