Name	python-lilv
Description	A C library interface to the LV2 plug-in standard - Python interface
Version	0.26.4-1
Package Base	lilv
Homepage	https://gitlab.com/lv2/lilv
Maintainers	['Christian Heusel <gromit@archlinux.org>', 'David Runge <dvzrv@archlinux.org>']
Contributors	['Ray Rashif <schiv@archlinux.org>', 'speps <speps@aur.archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/lilv
Sources	['https://download.drobilla.net/lilv-0.26.4.tar.xz', 'https://download.drobilla.net/lilv-0.26.4.tar.xz.sig']
Dependencies	['lilv', 'python', 'python-numpy']
Optional-Dependencies	[]
Build-Dependencies	['doxygen', 'libsndfile', 'lv2', 'meson', 'python', 'python-sphinx', 'python-sphinx-lv2-theme', 'python-sphinxygen', 'serd', 'sord', 'sratom', 'swig']
Provides	[]
Builddate	18-02-2026 01:53:27
Architecture	x86_64
Distro-Version
Licenses	['0BSD OR ISC', 'ISC']
Hash	139c6a96f343d90c4067a665cb1378755838f9a03f223ee4a45d506f71ca57a9

# Maintainer: David Runge <dvzrv@archlinux.org>
# Maintainer: Christian Heusel <gromit@archlinux.org>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: speps <speps at aur dot archlinux dot org>

pkgbase=lilv
pkgname=(
  lilv{,-docs}
  python-lilv
)
pkgver=0.26.4
pkgrel=1
pkgdesc="A C library interface to the LV2 plug-in standard"
arch=(x86_64)
url="https://gitlab.com/lv2/lilv"
license=(
  '0BSD OR ISC'
  ISC
)
makedepends=(
  doxygen
  libsndfile
  lv2
  meson
  python
  python-sphinx
  python-sphinx-lv2-theme
  python-sphinxygen
  serd
  sord
  sratom
  swig
)
source=(
  https://download.drobilla.net/$pkgname-$pkgver.tar.xz{,.sig}
)
sha512sums=('634b3f5e7a1763f9ea84dc8e41991e7dfa631457fc3c7beb8c7f627f1447da9e2d27f8389423de6ca508aaf00ef74c3b671166f194cd889952b267f7f0491cb6'
            'SKIP')
b2sums=('242e185a5e43f661505d1dd447db4394dc78ece0cce3f2ffc756544c2a7071bc01045b45c13e8aec5b2f6bca7033159f16ece1ed93e1ffee016c88453816b03d'
        'SKIP')
validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3') # David Robillard <d@drobilla.net>

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

build() {
  arch-meson $pkgname-$pkgver build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package_lilv() {
  depends=(
    glibc
    serd libserd-0.so
    sord libsord-0.so
    sratom libsratom-0.so
    lv2
    zix
  )
  optdepends=(
    'libsndfile: for lv2apply'
    'lilv-docs: for documentation'
    'python-lilv: for Python bindings'
  )
  provides=(liblilv-0.so)

  meson install -C build --destdir "$pkgdir"
  (
    cd "$pkgdir"
    _pick $pkgname-docs usr/share/doc
    _pick python-$pkgbase usr/lib/python*
  )

  install -vDm 644 $pkgbase-$pkgver/LICENSES/* -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 $pkgname-$pkgver/{NEWS,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
  # install bash completion to correct directory and remove /etc
  install -vDm 644 "$pkgdir/etc/bash_completion.d/$pkgname" -t "$pkgdir/usr/share/bash-completion/completions/"
  rm -frv "$pkgdir/etc"
}

package_lilv-docs() {
  pkgdesc+=" - documentation"

  mv -v $pkgname/* "$pkgdir"
  mv -v "$pkgdir/usr/share/doc/$pkgbase"{-0,}
  find "$pkgdir" -type f -iname "*.buildinfo" -delete
  install -vDm 644 $pkgbase-$pkgver/LICENSES/* -t "$pkgdir/usr/share/licenses/$pkgname/"
}

package_python-lilv() {
  pkgdesc+=" - Python interface"
  depends=(
    lilv
    python
    python-numpy
  )

  mv -v $pkgname/* "$pkgdir"
  install -vDm 644 $pkgbase-$pkgver/LICENSES/* -t "$pkgdir/usr/share/licenses/$pkgname/"
}