Name	python-yaml
Description	Python bindings for YAML, using fast libYAML library
Version	6.0.3-2
Package Base	python-yaml
Homepage	https://github.com/yaml/pyyaml
Maintainers	['David Runge <dvzrv@archlinux.org>', 'Jelle van der Waa <jelle@archlinux.org>', 'Levente Polyak <anthraxx[at]archlinux[dot]org>']
Contributors	['Michal Bozon <michal.bozon__at__gmail.com>', 'Sergej Pupykin <pupykin.s+arch@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/python-yaml
Sources	['pyyaml-6.0.3.tar.gz::https://github.com/yaml/pyyaml/archive/refs/tags/6.0.3.tar.gz']
Dependencies	['glibc', 'libyaml', 'python']
Optional-Dependencies	[]
Build-Dependencies	['cython', 'python-build', 'python-installer', 'python-setuptools', 'python-wheel']
Provides	['python-pyyaml']
Builddate	14-12-2025 17:35:35
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	2d7a34423bff947fb00c37d8d38c9595440d370cb07710be60c0d373709a25b2

# Maintainer: David Runge <dvzrv@archlinux.org>
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Michal Bozon <michal.bozon__at__gmail.com>

_name=pyyaml
pkgname=python-yaml
pkgver=6.0.3
pkgrel=2
pkgdesc='Python bindings for YAML, using fast libYAML library'
arch=(x86_64)
url='https://github.com/yaml/pyyaml'
license=(MIT)
depends=(
  glibc
  libyaml
  python
)
makedepends=(
  cython
  python-build
  python-installer
  python-setuptools
  python-wheel
)
checkdepends=(
  python-pytest
)
provides=(python-pyyaml)
source=($_name-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz)
sha512sums=('a0da43e32d127409ad61b11dc1d733b2e9c743977b3d72c05c81fc2ab183b40bc284452b0874dbeae1a736e1cd4a34f0df641ceefd5e9df38b3e53155fc5f633')
b2sums=('4cf50de6e2228072db914399072693d2b493c0d1ff099645397c0747fe67a3ec64f631a4ffc4c34eb6fd53cab80627bab068068b70632b3feadf887d9520214d')

build() {
  cd $_name-$pkgver
  python -m build --wheel --no-isolation --config-setting=--with-libyaml
}

check() {
  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")

  cd $_name-$pkgver
  # install to temporary location, as importlib is used
  python -m installer --destdir=test_dir dist/*.whl
  PYTHONPATH="$PWD/test_dir/$site_packages:$PYTHONPATH" pytest "${pytest_options[@]}"
}

package() {
  cd $_name-$pkgver
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm 644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  install -Dm 644 CHANGES README.md -t "$pkgdir"/usr/share/doc/$pkgname/
}

# vim: ts=2 sw=2 et: