Name	qt6-5compat
Description	Module that contains unsupported Qt 5 APIs
Version	6.10.2-1
Package Base	qt6-5compat
Homepage	https://www.qt.io
Maintainers	['Antonio Rojas <arojas@archlinux.org>', 'Felix Yan <felixonmars@archlinux.org>']
Contributors	['Andrea Scarpino <andrea@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/qt6-5compat
Sources	['git+https://code.qt.io/qt/qt5compat#tag=v6.10.2']
Dependencies	['gcc-libs', 'glibc', 'icu', 'qt6-base', 'qt6-shadertools']
Optional-Dependencies	['qt6-declarative']
Build-Dependencies	['cmake', 'git', 'ninja', 'qt6-declarative']
Provides	[]
Builddate	29-01-2026 10:53:57
Architecture	x86_64
Distro-Version
Licenses	['GPL-3.0-only', 'LGPL-3.0-only', 'LicenseRef-Qt-Commercial', 'Qt-GPL-exception-1.0']
Hash	ca397ac17bafdbe61c4df5c8d868c057cdcd47923e93aa0bd96a97a46ea46f36

# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=qt6-5compat
_pkgver=6.10.2
pkgver=${_pkgver/-/}
pkgrel=1
arch=(x86_64)
url='https://www.qt.io'
license=(GPL-3.0-only
         LGPL-3.0-only
         LicenseRef-Qt-Commercial
         Qt-GPL-exception-1.0)
pkgdesc='Module that contains unsupported Qt 5 APIs'
depends=(gcc-libs
         glibc
         icu
         qt6-base
         qt6-shadertools)
makedepends=(cmake
             git
             ninja
             qt6-declarative)
optdepends=('qt6-declarative: for QtGraphicalEffects')
groups=(qt6)
_pkgfn=${pkgname/6-/}
source=(git+https://code.qt.io/qt/$_pkgfn#tag=v$_pkgver)
sha256sums=('bbc3ec1ce80bc6e502cfd6b2b72b9192d6cb9e01af8df7b4e6affd70ec2fa418')

build() {
  cmake -B build -S $_pkgfn -G Ninja \
    -DCMAKE_MESSAGE_LOG_LEVEL=STATUS
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build

  install -d "$pkgdir"/usr/share/licenses
  ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
}