Name	quota-tools
Description	Tools to manage kernel-level quotas in Linux
Version	1:4.11-1
Package Base	quota-tools
Homepage	https://sourceforge.net/projects/linuxquota/
Maintainers	['Antonio Rojas <arojas@archlinux.org>']
Contributors	['Eric Bélanger <eric@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/quota-tools
Sources	['https://downloads.sourceforge.net/sourceforge/linuxquota/quota-4.11.tar.gz']
Dependencies	['dbus', 'e2fsprogs', 'glibc', 'libldap', 'libnl', 'libtirpc']
Optional-Dependencies	[]
Build-Dependencies	['rpcsvc-proto']
Provides	[]
Builddate	11-12-2025 22:23:08
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-or-later']
Hash	81e4565494c249e90e4bd2085e7dfce2ca1a89045ab7099372edf212438ddcb2

# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Eric Bélanger <eric@archlinux.org>

pkgname=quota-tools
pkgver=4.11
pkgrel=1
epoch=1
pkgdesc='Tools to manage kernel-level quotas in Linux'
arch=(x86_64)
url='https://sourceforge.net/projects/linuxquota/'
license=(GPL-2.0-or-later)
depends=(dbus
         e2fsprogs
         glibc
         libldap
         libnl
         libtirpc)
makedepends=(rpcsvc-proto)
backup=(etc/quotagrpadmins
        etc/quotatab
        etc/warnquota.conf)
source=(https://downloads.sourceforge.net/sourceforge/linuxquota/quota-$pkgver.tar.gz)
sha256sums=('0a51b8f920254d8e83c34a4c3082b7d241f5d6fd65188afadf29859d5223ef78')

build() {
  cd quota-$pkgver
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc
  make
}

package() {
  cd quota-$pkgver
  make DESTDIR="$pkgdir" sbindir=/usr/bin root_sbindir=/usr/bin STRIP="" install
  install -d "$pkgdir/usr/share/licenses/$pkgname"
  head -33 quota.c > "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

# remove conflicts with glibc
  rm -r "$pkgdir"/usr/include
}