Name	re2
Description	Fast, safe, thread-friendly regular expression engine
Version	2:2025.11.05-1
Package Base	re2
Homepage	https://github.com/google/re2
Maintainers	['Christian Heusel <gromit@archlinux.org>', 'Evangelos Foutras <foutrelis@archlinux.org>']
Contributors	['Alexandre Bique <bique.alexandre@gmail.com>', 'Anatol Pomozov <anatol.pomozov@gmail.com>', 'Gustavo Alvarez <sl1pkn07@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/re2
Sources	['re2::git+https://github.com/google/re2.git#tag=2025-11-05']
Dependencies	['abseil-cpp', 'gcc-libs', 'glibc']
Optional-Dependencies	[]
Build-Dependencies	['git', 'cmake']
Provides	['libre2.so']
Builddate	19-12-2025 04:08:21
Architecture	x86_64
Distro-Version
Licenses	['BSD-3-Clause']
Hash	ad29b1328223aa5af7311dc721e01a1c67676a3d205e2b68e1916ce30b12cf90

# Maintainer: Evangelos Foutras <foutrelis@archlinux.org>
# Maintainer: Christian Heusel <gromit@archlinux.org>
# Contributor: Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>
# Contributor: Alexandre Bique <bique.alexandre@gmail.com>

pkgname=re2
pkgrel=1
epoch=2
pkgver=2025.11.05
pkgdesc="Fast, safe, thread-friendly regular expression engine"
arch=('x86_64')
url="https://github.com/google/re2"
license=('BSD-3-Clause')
depends=('gcc-libs' 'glibc' 'abseil-cpp')
checkdepends=('gtest' 'benchmark')
makedepends=('git' 'cmake')
provides=('libre2.so')
source=("$pkgname::git+https://github.com/google/re2.git#tag=${pkgver//./-}")
sha256sums=('13cb4ba61567d496fc8ed0bc31369e81bbe9ef34ce8c7dffe5219093a576e385')

build() {
  local cmake_options=(
    -B build
    -S $pkgname
    -W no-dev
    -D CMAKE_BUILD_TYPE=None
    -D CMAKE_INSTALL_PREFIX=/usr
    -D BUILD_SHARED_LIBS=ON
    -D RE2_BUILD_TESTING=ON
  )
  cmake "${cmake_options[@]}"
  cmake --build build
}

check() {
  local excluded_tests=""
  local ctest_flags=(
    --test-dir build
    # show the stdout and stderr when the test fails
    --output-on-failure
    # execute tests in parallel
    --parallel $(nproc)
    # exclude problematic tests
    --exclude-regex "$excluded_tests"
  )
  ctest "${ctest_flags[@]}"
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 $pkgname/LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}