Name	sdl3
Description	A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 3)
Version	3.4.2-1
Package Base	sdl3
Homepage	https://www.libsdl.org
Maintainers	['Sven-Hendrik Haase <svenstaro@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/sdl3
Sources	['https://github.com/libsdl-org/SDL/releases/download/release-3.4.2/SDL3-3.4.2.tar.gz', 'https://github.com/libsdl-org/SDL/releases/download/release-3.4.2/SDL3-3.4.2.tar.gz.sig']
Dependencies	['glibc', 'hidapi', 'libgl', 'libusb', 'libx11', 'libxcursor', 'libxext', 'libxrender']
Optional-Dependencies	['alsa-lib', 'jack', 'libdecor', 'libpulse', 'pipewire', 'sndio', 'vulkan-driver']
Build-Dependencies	['cmake', 'ninja', 'jack', 'wayland-protocols', 'alsa-lib', 'mesa', 'libpulse', 'libxrandr', 'libxinerama', 'wayland', 'libxkbcommon', 'ibus', 'libxss', 'pipewire', 'libdecor', 'vulkan-headers', 'sndio']
Provides	[]
Builddate	22-02-2026 17:50:37
Architecture	x86_64
Distro-Version
Licenses	['Zlib']
Hash	f2f75dd48522ab8ad6c499e9b3dc959b2aa8e63dd133b47c1e68b8ab0d260218

# Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
pkgname=sdl3
pkgver=3.4.2
pkgrel=1
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 3)"
arch=('x86_64')
url="https://www.libsdl.org"
license=('Zlib')
depends=(
  'glibc'
  'libxext'
  'libxrender'
  'libx11'
  'libgl'
  'libxcursor'
  'hidapi'
  'libusb'
)
makedepends=(
  'cmake'
  'ninja'
  'jack'
  'wayland-protocols'
  'alsa-lib'
  'mesa'
  'libpulse'
  'libxrandr'
  'libxinerama'
  'wayland'
  'libxkbcommon'
  'ibus'
  'libxss'
  'pipewire'
  'libdecor'
  'vulkan-headers'
  'sndio'
)
optdepends=(
  'alsa-lib: ALSA audio driver'
  'libpulse: PulseAudio audio driver'
  'jack: JACK audio driver'
  'pipewire: PipeWire audio driver'
  'vulkan-driver: vulkan renderer'
  'sndio: sndio audio driver'
  'libdecor: Wayland client decorations'
)
source=("https://github.com/libsdl-org/SDL/releases/download/release-${pkgver}/SDL3-${pkgver}.tar.gz"{,.sig})
sha512sums=('3d9e9514788ecefea586e788af2100a73befffd2b4a9aaccbbe3b3e0c8cb324605b1386b4f7a65cb59022fbaab430efda164a3d1301cbf2315987018bc110f64'
            'SKIP')
validpgpkeys=('0900104363B4C9D4223DE149D913FE7D4B61D39B') # Sam Lantinga

build() {
  CFLAGS+=" -ffat-lto-objects"
  cmake -S SDL3-${pkgver} \
    -B build -G Ninja \
    -D CMAKE_BUILD_TYPE=None \
    -D CMAKE_INSTALL_PREFIX=/usr \
    -D SDL_STATIC=OFF \
    -D SDL_RPATH=OFF
  cmake --build build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
  install -Dm755 build/test/testcontroller "$pkgdir/usr/bin/testcontroller"
  install -Dm644 SDL3-${pkgver}/LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set ts=2 sw=2 et: