Name	serd-docs
Description	Lightweight C library for RDF syntax supporting reading/ writing Turtle and NTriples - documentation
Version	0.32.8-1
Package Base	serd
Homepage	https://drobilla.net/software/serd.html
Maintainers	['Christian Heusel <gromit@archlinux.org>', 'David Runge <dvzrv@archlinux.org>']
Contributors	['Ray Rashif <schiv@archlinux.org>', 'speps <speps@aur.archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/serd
Sources	['https://download.drobilla.net/serd-0.32.8.tar.xz', 'https://download.drobilla.net/serd-0.32.8.tar.xz.sig']
Dependencies	[]
Optional-Dependencies	[]
Build-Dependencies	['doxygen', 'mandoc', 'meson', 'python-sphinx', 'python-sphinxygen']
Provides	[]
Builddate	18-02-2026 01:48:04
Architecture	x86_64
Distro-Version
Licenses	['0BSD OR ISC', 'BSD-3-Clause', 'ISC']
Hash	1d285bc0a1432dfe17891e01c67a7a0d9f55c525c1394abc6304c5d51b428ec6

# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: speps <speps at aur dot archlinux dot org>

pkgbase=serd
pkgname=(serd serd-docs)
pkgver=0.32.8
pkgrel=1
pkgdesc="Lightweight C library for RDF syntax supporting reading/ writing Turtle and NTriples"
arch=(x86_64)
url="https://drobilla.net/software/serd.html"
license=(
  '0BSD OR ISC'
  BSD-3-Clause
  ISC
)
makedepends=(
  doxygen
  mandoc
  meson
  python-sphinx
  python-sphinxygen
)
source=(https://download.drobilla.net/$pkgname-$pkgver.tar.xz{,.sig})
sha512sums=('6cca335e658f4d0c5296924f04ea1d3cfa36e3927a753e87987c9214c4f0c30368c776bec0bc9369c073d6a6ed43d226c8ba57a7be372c26350395cbbae64dea'
            'SKIP')
b2sums=('63f892d599f787be3130f4024acd1116ae7c2e889f8223cd559ba11b575c77e88a8c8927b5089887ab6563d9d3ba96ea38498aba88a9444a8faef0607d1a11fa'
        'SKIP')
validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3') # David Robillard <d@drobilla.net>

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

build() {
  arch-meson $pkgname-$pkgver build
  meson compile -C build
}

check() {
  meson test -C build
}

package_serd() {
  depends=(glibc)
  optdepends=('serd-docs: for developer documentation')
  provides=(libserd-0.so)

  meson install -C build --destdir "$pkgdir"
  install -vDm 644 $pkgbase-$pkgver/LICENSES/* -t "$pkgdir/usr/share/licenses/$pkgname/"

  (
    cd "$pkgdir"
    _pick $pkgname-docs usr/share/doc
  )

  install -vDm 644 $pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 $pkgname-$pkgver/{AUTHORS,NEWS,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
}

package_serd-docs() {
  pkgdesc+=" - documentation"

  mv -v $pkgname/* "$pkgdir"
  mv -v "$pkgdir/usr/share/doc/"serd{-0,}
  install -vDm 644 $pkgbase-$pkgver/LICENSES/* -t "$pkgdir/usr/share/licenses/$pkgname/"
}