Name	shaderc
Description	Collection of tools, libraries and tests for shader compilation
Version	2026.1-2
Package Base	shaderc
Homepage	https://github.com/google/shaderc
Maintainers	['Levente Polyak <anthraxx[at]archlinux[dot]org>', 'Robin Candau <antiz@archlinux.org>']
Contributors	['Bin Jin <bjin@ctrl-d.org>', 'Daniel M. Capella <polycitizen@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/shaderc
Sources	['https://github.com/google/shaderc/archive/v2026.1/shaderc-2026.1.tar.gz']
Dependencies	['glibc', 'glslang', 'libgcc', 'libstdc++', 'spirv-tools']
Optional-Dependencies	[]
Build-Dependencies	['asciidoctor', 'cmake', 'ninja', 'python', 'spirv-headers']
Provides	['libshaderc_shared.so']
Builddate	24-02-2026 16:49:27
Architecture	x86_64
Distro-Version
Licenses	['Apache-2.0']
Hash	8cc98ccd7f4ff2d38c49ee3f94cf8c5ef8bec80722dbdf077fdf8516e7567b10

# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Robin Candau <antiz@archlinux.org>
# Contributor: Daniel M. Capella <polycitizen@gmail.com>
# Contributor: Bin Jin <bjin@ctrl-d.org>

pkgname=shaderc
pkgver=2026.1
pkgrel=2
pkgdesc='Collection of tools, libraries and tests for shader compilation'
url='https://github.com/google/shaderc'
arch=('x86_64')
license=('Apache-2.0')
depends=('glibc' 'glslang' 'libgcc' 'libstdc++' 'spirv-tools')
makedepends=('asciidoctor' 'cmake' 'ninja' 'python' 'spirv-headers')
provides=('libshaderc_shared.so')
source=(https://github.com/google/shaderc/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
sha512sums=('b8758884d5cd67f5536f30838295e618544df38e3ca3e2b1379757bc57464d333c3263c5fd19e5b4a735284fde7c3d4de9075a414691b2e86ba069bcff2cd616')
b2sums=('007fc3ae0442ae05a9309cb7cadb5595ad7f31d599c5c30bc574a62d569c895666277c7bab79e048ae4ff354c142b97c264354298fb709e4801b9ab9d0a5f5df')

prepare() {
  cd ${pkgname}-${pkgver}

  # de-vendor libs and disable git versioning
  sed '/examples/d;/third_party/d' -i CMakeLists.txt
  sed '/build-version/d' -i glslc/CMakeLists.txt
  cat <<- EOF > glslc/src/build-version.inc
"${pkgver}\\n"
"$(pacman -Q spirv-tools|cut -d \  -f 2|sed 's/-.*//')\\n"
"$(pacman -Q glslang|cut -d \  -f 2|sed 's/-.*//')\\n"
EOF
}

build() {
  cd ${pkgname}-${pkgver}
  cmake \
    -B build \
    -GNinja \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_CXX_FLAGS="$CXXFLAGS -ffat-lto-objects" \
    -DSHADERC_SKIP_TESTS=ON \
    -DPYTHON_EXECUTABLE=python \
    -Dglslang_SOURCE_DIR=/usr/include/glslang
  ninja -C build

  cd glslc
  asciidoctor -b manpage README.asciidoc -o glslc.1
}

check() {
  cd ${pkgname}-${pkgver}
  ninja -C build test
}

package() {
  cd ${pkgname}-${pkgver}
  DESTDIR="${pkgdir}" ninja -C build install
  install -Dm 644 glslc/glslc.1 -t "${pkgdir}/usr/share/man/man1"

  # Remove unused shaderc_static.pc
  rm "${pkgdir}/usr/lib/pkgconfig/shaderc_static.pc"
}

# vim: ts=2 sw=2 et: