Name	snappy
Description	A fast compressor/decompressor library
Version	1.2.2-3
Package Base	snappy
Homepage	https://github.com/google/snappy
Maintainers	['Anatol Pomozov', 'Carl Smedstad <carsme@archlinux.org>']
Contributors	['Antony Male <antony.male@geemail.com>>', 'Dave Reisner <dreisner@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/snappy
Sources	['git+https://github.com/google/snappy.git#tag=1.2.2', 'snappy-cmake_add_pkgconfig.patch', 'snappy-reenable_rtti.patch', 'snappy-use_system_gtest.patch', 'snappy.pc.in']
Dependencies	['glibc', 'libstdc++']
Optional-Dependencies	[]
Build-Dependencies	['clang', 'cmake', 'git', 'gtest']
Provides	['libsnappy.so']
Builddate	14-02-2026 22:59:20
Architecture	x86_64
Distro-Version
Licenses	['BSD-3-Clause']
Hash	7aad7fd4c96a392d5af1d6c03d635ac0c391e2e3856d20adaa88c19ca7848715

# Maintainer: Anatol Pomozov
# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: Dave Reisner <dreisner@archlinux.org>
# Contributor: Antony Male <antony dot male at geemail dot com>>

pkgname=snappy
pkgver=1.2.2
pkgrel=3
pkgdesc='A fast compressor/decompressor library'
arch=('x86_64')
url="https://github.com/google/snappy"
license=('BSD-3-Clause')
depends=(
  'glibc'
  'libstdc++'
)
makedepends=(
  'clang'
  'cmake'
  'git'
  'gtest'
)
checkdepends=('zlib')
provides=('libsnappy.so')
source=(
  "git+${url}.git#tag=${pkgver}"
  "snappy.pc.in"
  "$pkgname-cmake_add_pkgconfig.patch"
  "$pkgname-use_system_gtest.patch"
  "$pkgname-reenable_rtti.patch"
)
b2sums=('e529079f34d57078351014d958025104f6385c018c7164c1b9aeff75f2213d9fe6eb68fb63d11eff7474b83e08e264d733b83cc39c723d3d6f0c030c5340bed8'
        '01ded6bce04572813842383996941439fc7869b8f82cd5d13446c62c129c84d6cbb79d41a58c0076aa8687d22633e82a29d3169d33c9a9d6280848809177a89d'
        '5b4df9ff9534492bb4f14ace36353b7d2536a94e378f348d011a8578847e16946bc9e34e38657502e2732ea2953ef33d7d83fc24829412e0fbf9d4574bffcabe'
        '0c751bd1d57f70786c07c3579248db0d912d98cbcf2327eabbefe630dea45a1119db8f3bb190e718733f53b754080c4b335cd70ace944957ec81016e6087c8df'
        '8d8ae2b50e11a5945dac97d00932de17f05f3df0d9db202bbcf85c20b2c4a69ea4d28b82cbc762e38f03f5ab2d70abccedfd05648f00e7f5d20ff64d6c35f36b')

prepare() {
  cd $pkgname
  cp ../snappy.pc.in .
  patch -Np1 < ../$pkgname-cmake_add_pkgconfig.patch # https://bugs.archlinux.org/task/71246
  patch -Np1 < ../$pkgname-use_system_gtest.patch
  patch -Np1 < ../$pkgname-reenable_rtti.patch
}

build() {
  cmake -S $pkgname -B build \
    -D CMAKE_BUILD_TYPE=None \
    -D CMAKE_INSTALL_PREFIX=/usr \
    -W no-dev \
    -DCMAKE_CXX_STANDARD=23 \
    -DBUILD_SHARED_LIBS=ON \
    -DSNAPPY_BUILD_BENCHMARKS=OFF
  cmake --build build
}

check() {
  cmake --build build --target test
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" $pkgname/COPYING
}