Name	sord-docs
Description	A lightweight C library for storing RDF data in memory - documentation
Version	0.16.22-1
Package Base	sord
Homepage	https://drobilla.net/software/sord.html
Maintainers	['Christian Heusel <gromit@archlinux.org>', 'David Runge <dvzrv@archlinux.org>']
Contributors	['Ray Rashif <schiv@archlinux.org>', 'speps <speps@aur.archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/sord
Sources	['https://download.drobilla.net/sord-0.16.22.tar.xz', 'https://download.drobilla.net/sord-0.16.22.tar.xz.sig']
Dependencies	[]
Optional-Dependencies	[]
Build-Dependencies	['doxygen', 'glibc', 'meson', 'pcre2', 'python-sphinx', 'serd', 'zix']
Provides	[]
Builddate	18-02-2026 01:47:44
Architecture	x86_64
Distro-Version
Licenses	['ISC']
Hash	5f1f25eb8a82c472674f6765921e719e3b57edff65fd39652c2f072c4bec244a

# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: speps <speps at aur dot archlinux dot org>

pkgbase=sord
pkgname=(sord sord-docs)
pkgver=0.16.22
pkgrel=1
pkgdesc="A lightweight C library for storing RDF data in memory"
arch=(x86_64)
url="https://drobilla.net/software/sord.html"
license=(ISC)
makedepends=(
  doxygen
  glibc
  meson
  pcre2
  python-sphinx
  serd
  zix
)
source=(https://download.drobilla.net/$pkgname-$pkgver.tar.xz{,.sig})
sha512sums=('3821500f810e3b1cdbd763db419445c931d8b61de571f475646f11a5740c521c93c47ecab2e81a580a0d94bf432faa0de78fe3be1138c87bf9baca8fe23bb0cd'
            'SKIP')
b2sums=('82745bcaf18282c6aa4d36327f658191fcf61f8a3e9c822ecee1e98ae2e9c11c0654d42a4a0746e76a8ac72624a01fd47a14e9ccf14ee7e78728ee82cdcbdb0f'
        'SKIP')
validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3') # David Robillard <d@drobilla.net>

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

build() {
  arch-meson $pkgname-$pkgver build
  meson compile -C build
}

check() {
  meson test -C build
}

package_sord() {
  depends=(
    glibc
    pcre2
    serd libserd-0.so
    zix libzix-0.so
  )
  provides=(libsord-0.so)
  optdepends=('sord-docs: for developer documentation')

  meson install -C build --destdir "$pkgdir"
  (
    cd "$pkgdir"
    _pick $pkgname-docs usr/share/doc
  )
  install -vDm 644 $pkgname-$pkgver/LICENSES/*.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 $pkgname-$pkgver/{AUTHORS,NEWS,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
}

package_sord-docs() {
  pkgdesc+=" - documentation"

  mv -v $pkgname/* "$pkgdir"
  mv -v "$pkgdir/usr/share/doc/"sord{-0,}
}