Name	talloc
Description	Hierarchical pool based memory allocator with destructors
Version	2.4.4-1
Package Base	talloc
Homepage	https://talloc.samba.org/
Maintainers	['Antonio Rojas <arojas@archlinux.org>']
Contributors	['Tobias Powalowski <tpowa@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/talloc
Sources	['https://www.samba.org/ftp/talloc/talloc-2.4.4.tar.asc', 'https://www.samba.org/ftp/talloc/talloc-2.4.4.tar.gz']
Dependencies	['glibc', 'libbsd', 'libxcrypt']
Optional-Dependencies	['python']
Build-Dependencies	['python', 'docbook-xsl']
Provides	[]
Builddate	03-02-2026 23:38:15
Architecture	x86_64
Distro-Version
Licenses	['GPL-3.0-or-later']
Hash	346ebb251aa4af09ea6b2dffb15edc3952b253dd4930ea4b9f17366be1f2acc9

# Maintainer:
# Contributor: Tobias Powalowski <tpowa@archlinux.org>

pkgname=talloc
pkgver=2.4.4
pkgrel=1
pkgdesc="Hierarchical pool based memory allocator with destructors"
arch=('x86_64')
license=('GPL-3.0-or-later')
url="https://talloc.samba.org/"
depends=('glibc' 'libbsd' 'libxcrypt')
makedepends=('python' 'docbook-xsl')
optdepends=('python: for python bindings')
source=(https://www.samba.org/ftp/talloc/talloc-$pkgver.tar.{gz,asc})
sha512sums=('3273ef4f2de463293a515df8269cd585c46a1cae1889455d7c3438399541769cb5c55944ad77257ae6498cecbcc0c65bc81843b70d1f98b5e7fd107f67eec867'
            'SKIP')
validpgpkeys=(9147A339719518EE9011BCB54793916113084025) # samba-bugs@samba.org

build() {
   cd "${srcdir}/${pkgname}-${pkgver}"
   ./configure --prefix=/usr \
     --sysconfdir=/etc/samba \
     --localstatedir=/var \
     --bundled-libraries=NONE \
     --builtin-libraries=replace \
     --enable-talloc-compat1
   make
}

check() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make check
}

package() {
   cd "${srcdir}/${pkgname}-${pkgver}"
   make DESTDIR="${pkgdir}" install
}