Name	unixodbc
Description	ODBC is an open specification for providing application developers with a predictable API with which to access Data Sources
Version	2.3.14-1
Package Base	unixodbc
Homepage	http://www.unixodbc.org/
Maintainers	['Andreas Radke <andyrtr@archlinux.org>', 'AndyRTR <andyrtr@archlinux.org>']
Contributors	['Judd Vinet <jvinet@zeroflux.org>', 'Tom Newsom <Jeepster@gmx.co.uk>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/unixodbc
Sources	['https://github.com/lurcher/unixODBC/releases/download/v2.3.14/unixODBC-2.3.14.tar.gz']
Dependencies	['glibc', 'libltdl', 'readline']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	['libodbc.so', 'libodbccr.so', 'libodbcinst.so']
Builddate	07-10-2025 18:23:12
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-or-later', 'LGPL-2.1-or-later']
Hash	d0b371e06aec9f618668ac0a69fd48d9180c1f369d8df6ec5725b589f9e078ff

# Maintainer: AndyRTR <andyrtr@archlinux.org>
# Contributor: Judd Vinet <jvinet@zeroflux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

pkgname=unixodbc
pkgver=2.3.14
pkgrel=1
pkgdesc="ODBC is an open specification for providing application developers with a predictable API with which to access Data Sources"
arch=('x86_64')
license=('GPL-2.0-or-later' 'LGPL-2.1-or-later')
url="http://www.unixodbc.org/"
backup=('etc/odbc.ini' 'etc/odbcinst.ini')
depends=('readline' 'libltdl' 'glibc')
provides=('libodbc.so' 'libodbccr.so' 'libodbcinst.so')
source=(#ftp://ftp.unixodbc.org/pub/unixODBC/unixODBC-$pkgver.tar.gz
        https://github.com/lurcher/unixODBC/releases/download/v${pkgver}/unixODBC-${pkgver}.tar.gz)
sha256sums=('4e2814de3e01fc30b0b9f75e83bb5aba91ab0384ee951286504bb70205524771')

prepare() {
    cd unixODBC-${pkgver}
    autoreconf -vfi
}

build() {
    cd unixODBC-${pkgver}
    ./configure --prefix=/usr --sysconfdir=/etc
    sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
    make
}

check() {
    cd unixODBC-${pkgver}
    make -k check
}

package() {
    cd unixODBC-${pkgver}
    make DESTDIR="${pkgdir}" install
    touch "$pkgdir"/etc/{odbc,odbcinst}.ini
}