Name	v4l-utils
Description	Userspace tools and conversion library for Video 4 Linux
Version	1.32.0-1
Package Base	v4l-utils
Homepage	https://linuxtv.org/
Maintainers	['Jelle van der Waa <jelle@archlinux.org>', 'Thomas Bächler <thomas@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/v4l-utils
Sources	['https://linuxtv.org/downloads/v4l-utils/v4l-utils-1.32.0.tar.xz', 'https://linuxtv.org/downloads/v4l-utils/v4l-utils-1.32.0.tar.xz.asc']
Dependencies	['gcc-libs', 'hicolor-icon-theme', 'json-c', 'libbpf', 'libjpeg-turbo', 'systemd-libs']
Optional-Dependencies	['alsa-lib', 'qt6-5compat', 'qt6-base']
Build-Dependencies	['qt6-base', 'qt6-5compat', 'alsa-lib', 'meson', 'clang', 'doxygen']
Provides	['libv4l']
Builddate	18-10-2025 15:44:12
Architecture	x86_64
Distro-Version
Licenses	['LGPL']
Hash	fc9cc6d08cc113530c382c0d64eda1f196cbf0bea7a7dd5475cc89cfeaa1bab7

# Maintainer: Thomas Bächler <thomas@archlinux.org>
pkgname=v4l-utils
pkgver=1.32.0
pkgrel=1
pkgdesc="Userspace tools and conversion library for Video 4 Linux"
arch=('x86_64')
url="https://linuxtv.org/"
provides=("libv4l=$pkgver")
replaces=('libv4l')
conflicts=('libv4l')
backup=(etc/rc_maps.cfg)
license=('LGPL')
depends=('hicolor-icon-theme' 'gcc-libs' 'libbpf' 'libjpeg-turbo'  'systemd-libs' 'json-c')
makedepends=('qt6-base' 'qt6-5compat' 'alsa-lib' 'meson' 'clang' 'doxygen')
optdepends=('qt6-base: for qv4l2 and qvidcap'
            'qt6-5compat: for qv4l2'
            'alsa-lib: for qv4l2')
source=(https://linuxtv.org/downloads/v4l-utils/${pkgname}-${pkgver}.tar.xz{,.asc})
sha256sums=('6828828a17775526eb93fb258a9294d1d1073d633c344dd71ecd4e7a1ffb7dfc'
            'SKIP')
validpgpkeys=('05D0169C26E41593418129DF199A64FADFB500FF') # Gregor Jasny <gjasny@googlemail.com>

prepare() {
  # HACK: inform upstream to make this configurable
  cd "${pkgname}-${pkgver}"
  sed -i 's/sbin/bin/' utils/v4l2-dbg/meson.build
}

build() {
  arch-meson -Dgconv=disabled "${pkgname}-${pkgver}" build
  meson compile -C build
}

package() {
  meson install -C build --destdir "$pkgdir"
}