Name	vapoursynth
Description	A video processing framework with the future in mind
Version	73-2
Package Base	vapoursynth
Homepage	http://www.vapoursynth.com/
Maintainers	['Jelle van der Waa <jelle@archlinux.org>', 'Maxime Gauduin <alucryd@archlinux.org>']
Contributors	['jackoneill <cantabile.desu@gmail.com>', 'sl1pkn07 <sl1pkn07@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/vapoursynth
Sources	['git+https://github.com/vapoursynth/vapoursynth.git#tag=76762f6a07d5169c21903972f67827fc108020ba', 'vapoursynth.xml']
Dependencies	['libzimg.so', 'python']
Optional-Dependencies	[]
Build-Dependencies	['cython', 'git', 'python-sphinx']
Provides	[]
Builddate	14-12-2025 17:28:16
Architecture	x86_64
Distro-Version
Licenses	['LGPL2.1', 'custom:OFL']
Hash	f0802290dc7228aefaf0805720064d1f0243c0880f3fa9132051a5db9a112a8b

# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: sl1pkn07 <sl1pkn07@gmail.com>
# Contributor: jackoneill <cantabile.desu@gmail.com>

pkgname=vapoursynth
pkgver=73
pkgrel=2
pkgdesc='A video processing framework with the future in mind'
arch=(x86_64)
url=http://www.vapoursynth.com/
license=(
  LGPL2.1
  custom:OFL
)
depends=(
  libzimg.so
  python
)
makedepends=(
  cython
  git
  python-sphinx
)
_tag=76762f6a07d5169c21903972f67827fc108020ba
source=(
  git+https://github.com/vapoursynth/vapoursynth.git#tag=${_tag}
  vapoursynth.xml
)
b2sums=('4fb5b185c5b8192fbe7df974837409afb4b8748db4d439689852e79a195561d5ab4714bee879dee2a3be21e52c8c3455418ac327f307d069794a6a0b6b05399e'
        'feae23a22f8589177f30c36bdf21bab93d55a786194d3e0e958537016630d075b82178f60ac840f30ae316a8f87d3fb01f371211f62d1fee9850ee5063561747')

pkgver() {
  cd vapoursynth
  git describe --tags | sed 's/^R//'
}

prepare() {
  cd vapoursynth
  ./autogen.sh
}

build() {
  cd vapoursynth
  ./configure \
    --prefix=/usr \
    --disable-static
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd vapoursynth

  make DESTDIR="${pkgdir}" install

  install -Dm 644 src/core/ter-116n.ofl.txt -t "${pkgdir}"/usr/share/licenses/vapoursynth/
  install -Dm 644 ../vapoursynth.xml -t "${pkgdir}"/usr/share/mime/packages/
}

# vim: ts=2 sw=2 et: