Name	vmaf
Description	Perceptual video quality assessment algorithm based on multi-method fusion
Version	3.0.0-2
Package Base	vmaf
Homepage	https://github.com/Netflix/vmaf/
Maintainers	['Daniel Bermond <dbermond@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/vmaf
Sources	['https://github.com/Netflix/vmaf/archive/v3.0.0/vmaf-3.0.0.tar.gz']
Dependencies	['glibc', 'libgcc', 'libstdc++']
Optional-Dependencies	[]
Build-Dependencies	['meson', 'nasm']
Provides	[]
Builddate	15-02-2026 16:32:55
Architecture	x86_64
Distro-Version
Licenses	['BSD-2-Clause-Patent']
Hash	9301153032f70b5ed2fafd06bc96c1ce1bec31b17198ceab09edd50a9d122aeb

# Maintainer: Daniel Bermond <dbermond@archlinux.org>

pkgname=vmaf
pkgver=3.0.0
pkgrel=2
pkgdesc='Perceptual video quality assessment algorithm based on multi-method fusion'
arch=('x86_64')
url='https://github.com/Netflix/vmaf/'
license=('BSD-2-Clause-Patent')
depends=(
    'glibc'
    'libgcc'
    'libstdc++')
makedepends=(
    'meson'
    'nasm')
checkdepends=(
    'vim')
source=("https://github.com/Netflix/vmaf/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('7178c4833639e6b989ecae73131d02f70735fdb3fc2c7d84bc36c9c3461d93b1')

build() {
    arch-meson -Denable_avx512='false' "${pkgname}-${pkgver}/libvmaf" build
    meson compile -C build
}

check() {
    meson test -C build
}

package() {
    meson install -C build --destdir "$pkgdir"
    install -D -m644 "${pkgname}-${pkgver}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
    cp -dr --no-preserve='ownership' "${pkgname}-${pkgver}/model" "${pkgdir}/usr/share"
}