Name	vpl-gpu-rt
Description	Intel VPL runtime implementation for Intel GPUs (Tiger Lake and newer)
Version	25.3.4-2
Package Base	vpl-gpu-rt
Homepage	https://github.com/intel/vpl-gpu-rt/
Maintainers	['Daniel Bermond <dbermond@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/vpl-gpu-rt
Sources	['010-vpl-gpu-rt-disable-verbose-makefile.patch', 'https://github.com/intel/vpl-gpu-rt/archive/intel-onevpl-25.3.4/vpl-gpu-rt-25.3.4.tar.gz']
Dependencies	['glibc', 'intel-media-driver', 'libdrm', 'libgcc', 'libstdc++', 'libva']
Optional-Dependencies	[]
Build-Dependencies	['cmake']
Provides	['onevpl-intel-gpu', 'vpl-runtime']
Builddate	15-02-2026 18:45:49
Architecture	x86_64
Distro-Version
Licenses	['MIT']
Hash	92e822b901ed8915d70f16f506db99c8cc80f707d5dc0f2e6fc10a951a1820db

# Maintainer: Daniel Bermond <dbermond@archlinux.org>

pkgname=vpl-gpu-rt
pkgver=25.3.4
pkgrel=2
pkgdesc='Intel VPL runtime implementation for Intel GPUs (Tiger Lake and newer)'
arch=('x86_64')
url='https://github.com/intel/vpl-gpu-rt/'
license=('MIT')
depends=(
    'glibc'
    'intel-media-driver'
    'libdrm'
    'libgcc'
    'libstdc++'
    'libva')
makedepends=('cmake')
provides=('onevpl-intel-gpu' 'vpl-runtime')
conflicts=('onevpl-intel-gpu')
replaces=('onevpl-intel-gpu')
source=("https://github.com/intel/vpl-gpu-rt/archive/intel-onevpl-${pkgver}/${pkgname}-${pkgver}.tar.gz"
        '010-vpl-gpu-rt-disable-verbose-makefile.patch')
sha256sums=('8640073f161f6c2b919f37c8d1e8688a0e6f9b7590a2399cc0d2a89910afeafc'
            'c6b17b7026d16d02c3cab7b5081366c24021a86fa173eaee5db310691ce76879')

prepare() {
    patch -d "vpl-gpu-rt-intel-onevpl-${pkgver}" -Np1 -i "${srcdir}/010-vpl-gpu-rt-disable-verbose-makefile.patch"
}

build() {
    export CFLAGS+=' -DNDEBUG'
    export CXXFLAGS+=' -DNDEBUG'
    cmake -B build -S "vpl-gpu-rt-intel-onevpl-${pkgver}" \
        -G 'Unix Makefiles' \
        -DCMAKE_BUILD_TYPE:STRING='None' \
        -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
        -DBUILD_TESTS:BOOL='OFF' \
        -DMFX_ENABLE_AENC:BOOL='ON' \
        -Wno-dev
    cmake --build build
}

package() {
    DESTDIR="$pkgdir" cmake --install build
    install -D -m644 "vpl-gpu-rt-intel-onevpl-${pkgver}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}