Name	vulkan-icd-loader
Description	Vulkan Installable Client Driver (ICD) Loader
Version	1.4.341.0-1
Package Base	vulkan-icd-loader
Homepage	https://www.vulkan.org/
Maintainers	['Jan Alexander Steffens (heftig) <heftig@archlinux.org>', 'Laurent Carlier <lordheavym@gmail.com>', 'Robin Candau <antiz@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/vulkan-icd-loader
Sources	['git+https://github.com/KhronosGroup/Vulkan-Loader#tag=vulkan-sdk-1.4.341.0']
Dependencies	['glibc']
Optional-Dependencies	['vulkan-driver']
Build-Dependencies	['cmake', 'git', 'libx11', 'libxrandr', 'ninja', 'python-lxml', 'vulkan-headers', 'wayland']
Provides	['libvulkan.so']
Builddate	03-02-2026 10:22:16
Architecture	x86_64
Distro-Version
Licenses	['Apache-2.0']
Hash	cf25c6f418a7f48c37d1cc422c5bf3edeae3f17b1f4a297dd31b5b1e39af7f64

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Maintainer: Laurent Carlier <lordheavym@gmail.com>
# Maintainer: Robin Candau <antiz@archlinux.org>

pkgname=vulkan-icd-loader
pkgver=1.4.341.0
pkgrel=1
pkgdesc="Vulkan Installable Client Driver (ICD) Loader"
url="https://www.vulkan.org/"
arch=(x86_64)
license=(Apache-2.0)
depends=(glibc)
makedepends=(
  cmake
  git
  libx11
  libxrandr
  ninja
  python-lxml
  vulkan-headers
  wayland
)
optdepends=(
  # vulkan-driver: vulkan-intel/vulkan-radeon/nvidia-utils/....
  'vulkan-driver: packaged vulkan driver'
)
provides=(libvulkan.so)
groups=(vulkan-devel)
source=("git+https://github.com/KhronosGroup/Vulkan-Loader#tag=vulkan-sdk-$pkgver")
b2sums=('fd0c4ae2c938fc9134888ac582c59e5e83b14142cd74f0daa8b831b8fea45d67e10ddae3b4c551ce1520a2645fd5564bb4e977aa4df1c3dfb209db783c12c73a')

build() {
  local cmake_options=(
    -D CMAKE_BUILD_TYPE=Release
    -D CMAKE_INSTALL_PREFIX=/usr
    -D CMAKE_INSTALL_SYSCONFDIR=/etc
    -D CMAKE_SKIP_INSTALL_RPATH=ON
  )

  cmake -S Vulkan-Loader -B build -G Ninja "${cmake_options[@]}"
  cmake --build build
}

check() {
  ctest --test-dir build --output-on-failure --stop-on-failure
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}

# vim:set sw=2 sts=-1 et: