Name	x264
Description	Open Source H264/AVC video encoder
Version	3:0.165.r3222.b35605a-2
Package Base	x264
Homepage	https://www.videolan.org/developers/x264.html
Maintainers	['Lukas Fleischer <lfleischer@archlinux.org>', 'Maxime Gauduin <alucryd@archlinux.org>']
Contributors	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Ionut Biru <ibiru@archlinux.org>', 'Paul Mattal <paul@archlinux.org>', 'damir <damir@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/x264
Sources	['git+https://code.videolan.org/videolan/x264.git#commit=b35605ace3ddf7c1a5d67a2eb553f034aef41d55']
Dependencies	['glibc', 'liblsmash.so']
Optional-Dependencies	[]
Build-Dependencies	['git', 'nasm']
Provides	['libx264', 'libx264.so']
Builddate	24-09-2025 18:59:03
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-only']
Hash	c448740d7be83a63d52f1573984d3f878afec7eab21c4424727c72c639922bb7

# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: damir <damir@archlinux.org>
# Contributor: Paul Mattal <paul@archlinux.org>

pkgname=x264
pkgver=0.165.r3222.b35605a
pkgrel=2
epoch=3
pkgdesc='Open Source H264/AVC video encoder'
arch=(x86_64)
url=https://www.videolan.org/developers/x264.html
license=(GPL-2.0-only)
depends=(
  glibc
  liblsmash.so
)
makedepends=(
  git
  nasm
)
provides=(
  libx264
  libx264.so
)
conflicts=(
  libx264
  libx264-10bit
  libx264-all
)
replaces=(
  libx264
  libx264-10bit
  libx264-all
)
_commit=b35605ace3ddf7c1a5d67a2eb553f034aef41d55
source=(git+https://code.videolan.org/videolan/x264.git#commit=${_commit})
sha256sums=(SKIP)

pkgver() {
  cd x264
  ./version.sh | grep X264_POINTVER | sed -r 's/^#define X264_POINTVER "([0-9]+\.[0-9]+)\.([0-9]+) (.*)"$/\1.r\2.\3/'
}

build() {
  cd x264
  ./configure \
    --prefix=/usr \
    --enable-shared \
    --enable-pic \
    --enable-lto \
    --disable-avs
  make
}

package() {
  make -C x264 DESTDIR="${pkgdir}" BASHCOMPLETIONSDIR="/usr/share/bash-completion/completions" install-cli install-lib-shared install-bashcompletion
}

# vim: ts=2 sw=2 et: