Name	xdg-desktop-portal-gtk
Description	A backend implementation for xdg-desktop-portal using GTK
Version	1.15.3-1
Package Base	xdg-desktop-portal-gtk
Homepage	https://github.com/flatpak/xdg-desktop-portal-gtk
Maintainers	['Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Patrick Griffis <tingping@tingping.se>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/xdg-desktop-portal-gtk
Sources	['git+https://github.com/flatpak/xdg-desktop-portal-gtk#tag=1.15.3']
Dependencies	['fontconfig', 'gcc-libs', 'gdk-pixbuf2', 'glib2', 'glibc', 'gsettings-desktop-schemas', 'gtk3', 'xdg-desktop-portal']
Optional-Dependencies	['evince']
Build-Dependencies	['git', 'glib2-devel', 'meson', 'python', 'python-packaging']
Provides	['xdg-desktop-portal-impl']
Builddate	24-03-2025 03:58:22
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.0-or-later']
Hash	ff74ba4f426ff0d17c27aa556c041db7ee91b82d35748963f813b05637594a00

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Patrick Griffis <tingping@tingping.se>

pkgname=xdg-desktop-portal-gtk
pkgver=1.15.3
pkgrel=1
pkgdesc="A backend implementation for xdg-desktop-portal using GTK"
url="https://github.com/flatpak/xdg-desktop-portal-gtk"
arch=(x86_64)
license=(LGPL-2.0-or-later)
depends=(
  fontconfig
  gcc-libs
  gdk-pixbuf2
  glib2
  glibc
  gsettings-desktop-schemas
  gtk3
  xdg-desktop-portal
)
makedepends=(
  git
  glib2-devel
  meson
  python
  python-packaging
)
optdepends=("evince: Print preview")
provides=(xdg-desktop-portal-impl)
source=("git+$url#tag=$pkgver")
b2sums=('5acf381c294f59542268b888f543871e178679604ca5d22aa7b60882916ee0b274b5374d99910341aef27e2e9dfc8c1f047505bae2acd7c238ab9f0abf553a5a')

prepare() {
  cd $pkgname
}

build() {
  local meson_options=(
    -D wallpaper=disabled
  )

  arch-meson $pkgname build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"

  # fix detection with x-d-p 1.18
  install -Dm644 /dev/stdin "$pkgdir/usr/share/xdg-desktop-portal/gtk-portals.conf" <<END
[preferred]
default=gtk
END
}

# vim:set sw=2 sts=-1 et: