Name	xz
Description	Library and command line tools for XZ and LZMA compressed files
Version	5.8.2-1
Package Base	xz
Homepage	https://tukaani.org/xz/
Maintainers	['Christian Hesse <eworm@archlinux.org>', 'Pierre Schmitz <pierre@archlinux.de>']
Contributors	['François Charette <firmicus@gmx.net>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/xz
Sources	['git+https://github.com/tukaani-project/xz#tag=v5.8.2?signed']
Dependencies	['glibc', 'sh']
Optional-Dependencies	[]
Build-Dependencies	['git', 'po4a', 'doxygen']
Provides	['liblzma.so']
Builddate	17-12-2025 16:16:27
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-or-later AND 0BSD AND LicenseRef-Public-Domain AND LGPL-2.1-or-later']
Hash	23bcea71064a929c76f95a324b68e6856a8880c6f70d525f4a83c391ca07b88a

# Maintainer: Pierre Schmitz <pierre@archlinux.de>
# Contributor: François Charette <firmicus@gmx.net>

pkgname=xz
pkgver=5.8.2
pkgrel=1
pkgdesc='Library and command line tools for XZ and LZMA compressed files'
arch=('x86_64')
url='https://tukaani.org/xz/'
license=("GPL-2.0-or-later AND 0BSD AND LicenseRef-Public-Domain AND LGPL-2.1-or-later")
depends=(
  glibc
  sh
)
makedepends=('git' 'po4a' 'doxygen')
provides=('liblzma.so')
validpgpkeys=('3690C240CE51B4670D30AD1C38EE757D69184620') # Lasse Collin <lasse.collin@tukaani.org>
source=("git+https://github.com/tukaani-project/xz#tag=v${pkgver}?signed")
sha256sums=('c340ab4c34626b505d86824f1b2365a0314791c8edcacb201b67d112c54b94c0')
sha512sums=('328fe243e5701ac8216d21168a9e17ea9475cc08b27659c18b68230d8ddd0fffa9f831c576b08c160774fe2c4795604f82b64113e7f84db417b4bd26a4dae2c1')

prepare() {
  cd ${pkgname}

  ./autogen.sh
}

build() {
  cd ${pkgname}

  ./configure \
    --prefix=/usr \
    --disable-rpath \
    --enable-doxygen \
    --enable-werror
  make
}

check() {
  cd ${pkgname}

  make check
}

package() {
  cd ${pkgname}

  make DESTDIR="${pkgdir}" install

  install -d -m0755 "${pkgdir}/usr/share/licenses/xz/"
  local file
  for file in "${pkgdir}"/usr/share/doc/xz/COPYING*; do
    ln -sf "/usr/share/doc/xz/$(basename "${file}")" "${pkgdir}/usr/share/licenses/xz/"
  done
}