Name	zimg
Description	Scaling, colorspace conversion, and dithering library
Version	3.0.6-1
Package Base	zimg
Homepage	https://github.com/sekrit-twc/zimg
Maintainers	['Maxime Gauduin <alucryd@archlinux.org>']
Contributors	['Gustavo Alvarez <sl1pkn07@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/zimg
Sources	['git+https://github.com/sekrit-twc/zimg.git#tag=f819b14e8f39d1282400b0d9543e8ef73c1b2bbd']
Dependencies	['gcc-libs', 'glibc']
Optional-Dependencies	[]
Build-Dependencies	['git']
Provides	['libzimg.so']
Builddate	07-12-2025 19:38:47
Architecture	x86_64
Distro-Version
Licenses	['custom:WTFPL']
Hash	ffa3b42a1ac35747edadb96a0dc848f02e3b01054c4444bc4bca1dd8391cbf68

# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgname=zimg
pkgver=3.0.6
pkgrel=1
pkgdesc='Scaling, colorspace conversion, and dithering library'
arch=(x86_64)
url=https://github.com/sekrit-twc/zimg
license=(custom:WTFPL)
depends=(
  gcc-libs
  glibc
)
makedepends=(git)
provides=(libzimg.so)
options=(!emptydirs)
_tag=f819b14e8f39d1282400b0d9543e8ef73c1b2bbd
source=(git+https://github.com/sekrit-twc/zimg.git#tag=${_tag})
sha256sums=('3799202bd28d00bcf91fa772c303bb78f028394c9d2d123f694dae27aab9bea5')

prepare() {
  cd zimg
  ./autogen.sh
}

pkgver() {
  cd zimg
  git describe --tags | sed 's/^release-//'
}

build() {
  cd zimg
  ./configure \
    --prefix=/usr \
    --enable-x86simd \
    --disable-static
  make
}

package(){
  make DESTDIR="${pkgdir}" -C zimg install
  install -Dm 644 zimg/COPYING -t "${pkgdir}"/usr/share/licenses/zimg/
}

# vim: ts=2 sw=2 et: