Name	zix-docs
Description	A lightweight C99 portability and data structure library - documentation
Version	0.8.0-1
Package Base	zix
Homepage	https://gitlab.com/drobilla/zix
Maintainers	['Christian Heusel <gromit@archlinux.org>', 'David Runge <dvzrv@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/zix
Sources	['https://download.drobilla.net/zix-0.8.0.tar.xz', 'https://download.drobilla.net/zix-0.8.0.tar.xz.sig']
Dependencies	[]
Optional-Dependencies	[]
Build-Dependencies	['doxygen', 'glibc', 'meson', 'python-sphinx', 'python-sphinx-lv2-theme', 'python-sphinxygen']
Provides	[]
Builddate	01-12-2025 19:07:09
Architecture	x86_64
Distro-Version
Licenses	['0BSD OR ISC']
Hash	98d876697157e6c13c6fdc1c1f0eed2c09be71608b2d948e366ded9166721b61

# Maintainer: David Runge <dvzrv@archlinux.org>
# Maintainer: Christian Heusel <gromit@archlinux.org>

pkgbase=zix
pkgname=(zix{,-docs})
pkgver=0.8.0
pkgrel=1
pkgdesc="A lightweight C99 portability and data structure library"
arch=(x86_64)
url="https://gitlab.com/drobilla/zix"
license=('0BSD OR ISC')
makedepends=(
  doxygen
  glibc
  meson
  python-sphinx
  python-sphinx-lv2-theme
  python-sphinxygen
)
source=(https://download.drobilla.net/$pkgname-$pkgver.tar.xz{,.sig})
sha512sums=('fccb3e3b05c4d28e7fa6ed94537681167e2ee22a23dd4e1b4f3e5474da8dce3fe682cc6ccda219d140b956014c444a6f721d7272f3dba52df3a07e13b594f963'
            'SKIP')
b2sums=('c800585d7fcfd55a7f241c38fa8cfca5f58795bf78189371dd15c77a17f56221266749f1bc9a74fc7ff2b17991ddc05d4960649943706ed108e062447fe20c6c'
        'SKIP')
validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3') # David Robillard <d@drobilla.net>

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

build() {
  arch-meson $pkgname-$pkgver build
  meson compile -C build
}

check() {
  # ignore entire test suite, because of failing tests:
  # https://gitlab.com/drobilla/zix/-/issues/2
  meson test -C build --no-suite 'zix:unit'
}

package_zix() {
  depends=(glibc)
  optdepends=('zix-docs: for developer documentation')
  provides=(libzix-0.so)

  meson install -C build --destdir "$pkgdir"
  (
    cd "$pkgdir"
    _pick $pkgname-docs usr/share/doc
  )

  install -vDm 644 $pkgname-$pkgver/LICENSES/* -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 $pkgname-$pkgver/{NEWS,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
}

package_zix-docs() {
  pkgdesc+=" - documentation"

  mv -v $pkgname/* "$pkgdir"
  mv -v "$pkgdir/usr/share/doc/$pkgbase"{-0,}
}